home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 26 / CU Amiga Magazine's Super CD-ROM 26 (1998)(EMAP Images)(GB)[!][issue 1998-09].iso / InitCD < prev    next >
AmigaDOS Script File  |  1998-07-23  |  6KB  |  205 lines
  1. .key arg
  2. .bra {
  3. .ket }
  4.  
  5. ; CUCD Init Script
  6. ;
  7. ; Set up assigns etc. both for users booting from the CD and from  HD
  8. ;
  9. ; Version 1.1 - Changed jpegtmp
  10. ;
  11. ; Version 1.2 - Added uninit option
  12. ;
  13. ; Version 1.3 - Added CHECK argument and link to Prefs editor
  14. ;
  15. ; Version 1.4 - Added section to copy CUCDfile and IDer.prefs to hard drive if not already present
  16. ;
  17. ; Version 1.5 - Got rid of calls to updatecopy and replaced them with version/if warn
  18. ;               Hopefully cured the problem of the CD icon not leaving Workbench after running UninitCD
  19.  
  20. Assign CUCD: :
  21.  
  22. ;;; Make some commands resident to speed up things on CD32s in particular
  23. Resident >NIL: CUCD:C/RequestChoice PURE
  24. Resident >NIL: CUCD:rexxc/rx PURE
  25. Resident >NIL: CUCD:C/Version PURE
  26. ;;;
  27. ;;; Exit if InitCD has been run, otherwise ask
  28. If {arg} EQ "CHECK"
  29.     If $CDInit EQ TRUE
  30.         Skip END
  31.     Else
  32.         set init `CUCD:C/RequestChoice "CU Amiga CD" "InitCD needs to be run first*NWould you like to run it now?" "Yes|No"`
  33.         If $init EQ 0
  34.             Skip END
  35.             EndIf
  36.         EndIf
  37.     EndIf
  38. ;;;
  39. ;;; Give option to run UninitCD
  40. If $CDInit EQ TRUE
  41.     If $CDBoot EQ TRUE          ; don't run UninitCD if booted from CD
  42.         CUCD:C/RequestChoice >NIL: "CU Amiga CD" "You do not need to run InitCD*Nwhen you have booted from the CD" "OK" 
  43.         Skip END
  44.         EndIf
  45.     set remass `CUCD:C/RequestChoice "InitCD" "You have already run InitCD once.*NDo you wish to remove the assigns and paths added before?" "Remove|Cancel"`
  46.     If $remass EQ 1
  47.         execute UnInitCD
  48.         EndIf
  49.     Skip END
  50.     EndIf
  51. ;;;
  52. ;;; Set some system assigns and paths
  53. Assign WWW:             CUCD:CUCD/WWW
  54. Assign tcpdldir:        CUCD:CUCD/WWW
  55. Assign CUCDNews:        CUCD:CUCD/Online/News
  56. Assign Twist:           CUCD:CUCD/Magazine/Issues
  57. Assign TwistIcon:       Twist:Icons
  58. Assign libx11: EXISTS >NIL:
  59. If WARN
  60.     Assign libx11: CUCD:libs/libx11 ADD
  61.     EndIf
  62. ;;;
  63. ;;; Add MUI if no MUI installed.
  64. Assign MUI: EXISTS >NIL:
  65. IF WARN
  66.     Assign MUI:    CUCD:CDsupport/MUI
  67.     Assign Libs:   MUI:Libs ADD
  68.     Assign LOCALE: MUI:Locale ADD
  69.     Assign HELP: EXISTS >NIL:
  70.     If NOT WARN
  71.         Dir >NIL: HELP:
  72.         EndIf
  73.     Assign HELP:   MUI:Docs ADD
  74.     EndIf
  75. ;;;
  76. ;;; Set assigns and paths for programs on this CD
  77. Execute CUCD:S/ThisCD
  78. ;;;
  79. ;;;BEGIN ClassAct
  80. CUCD:C/CAPrefs >NIL:
  81. ;;;END ClassAct
  82. ;;; Commands to be run only if booting from CD
  83. IF $CDBoot EQ TRUE
  84.     Run <NIL: >NIL: C:NewIcons
  85.     CUCD:C/DefIcons
  86.  
  87.     ; Run these only if booting from a real CD32
  88.     Version >NIL:
  89.     if $kickstart EQ "40.60"
  90.         ;C:CD2XSpeed
  91.         C:NoReset
  92.         EndIf
  93.  
  94.     ; Allow alternative screenmodes
  95.     if $CUCDscreen EQ "NTSC"
  96.         :Storage/Monitors/NTSC
  97.         :Prefs/ScreenMode from :Prefs/Presets/NTSC USE
  98.         :Prefs/Input from :Prefs/Presets/USkey USE
  99.         setenv VisageOpts MONITOR=NTSC
  100.         endif
  101.     if $CUCDscreen EQ "VGA"
  102.         :Storage/Monitors/DblPAL
  103.         :Prefs/ScreenMode from :Prefs/Presets/VGA USE
  104.         setenv VisageOpts MONITOR=DblPAL
  105.         endif
  106.     unsetenv CUCDscreen
  107. ;;;
  108. ;;; All this is only needed when not booting from the CD
  109. Else
  110.     ; Make sure LIBS: has up to date copy of asyncio.library, to fix problems with earlier InitCD
  111.     Version >NIL: LIBS:asyncio.library 39 2 file
  112.     If WARN
  113.         copy CUCD:Libs/asyncio.library LIBS: CLONE
  114.         EndIf
  115.  
  116.     ; add CD assigns and paths
  117.     Assign DEVS:    CUCD:Devs ADD
  118.     Assign Fonts:   CUCD:Fonts ADD
  119.     Assign Libs:    CUCD:Libs ADD
  120.     Assign L:       CUCD:L ADD
  121.     Assign S:       CUCD:S ADD
  122.     Assign LIBS:    CUCD:Classes ADD
  123.     Path CUCD:C CUCD:CDsupport CUCD:System CUCD:Utilities CUCD:S CUCD:Rexxc ADD
  124.  
  125.     ; Start arexx if not running
  126.     CUCD:rexxc/rx "address command" >NIL:
  127.     If WARN
  128.         CUCD:System/RexxMast >NIL:
  129.         EndIf
  130.     ; Make sure icon.mcc is available for CUCDprefs
  131.     Version >NIL: MUI:Libs/MUI/Icon.mcc 1 1
  132.     If WARN
  133.         Copy >NIL: CUCD:CDsupport/MUI/Libs/MUI/Icon.mcc MUI:Libs/MUI CLONE
  134.         EndIf
  135.  
  136.     ; Give option for setting CD preferences, make sure CUCDfile and IDer
  137.     ; are in basic command path, so it will run without InitCD
  138.     If NOT EXISTS C:CUCDfile
  139.         Copy >NIL: CUCD:C/CUCDfile C: CLONE
  140.         EndIf
  141.     Version >NIL: C:IDer 1 6
  142.     If WARN
  143.         Copy >NIL: CUCD:C/IDer C: CLONE
  144.         EndIf
  145.     ; ensure IDer.prefs are available
  146.     If NOT EXISTS ENV:IDer.prefs
  147.         If NOT EXISTS S:IDer.prefs
  148.             Version >NIL: version 39
  149.             If NOT WARN
  150.                 Copy >NIL: CUCD:S/IDer.prefs S:IDer.prefs
  151.                 set edit `RequestChoice "CU Amiga CD" "CUCD now has a preferences program to specify*N the tools used to view/hear different types of files.*NWould you like to run it now?" "Yes|No"`
  152.                 If $edit EQ 1
  153.                     cd CUCD:S
  154.                     :RexxC/MuiRexx CUCDPrefs.mrx port CDPREFS
  155.                 Else
  156.                     RequestChoice >NIL: "CU Amiga CD" "You can run CUCD preferences at any time.*NIt is in the Prefs drawer of the CD" "OK"
  157.                     EndIf
  158.             Else
  159.                 Copy >NIL: CUCD:S/IDer.prefs_OS2 ENV:IDer.prefs
  160.                 EndIf
  161.             EndIf
  162.         EndIf
  163.  
  164.     ; Make environment variables defined on CD available to system
  165.     Failat 21
  166.     Assign >NIL: ENV: CUCD:Prefs/Env-Archive ADD
  167.     ; For HappyENV users
  168.     If FAIL     
  169.         Assign >NIL: ENVARC: CUCD:Prefs/Env-Archive ADD
  170.         EndIf
  171.  
  172.     ;Start NewIcons if not already running
  173.     If $NoNewIcons NOT EQ TRUE
  174.         CUCD:C/isnirunning
  175.         If NOT WARN
  176.             Run <NIL: >NIL: CUCD:C/NewIcons
  177.             CUCD:C/DefIcons
  178.             EndIf
  179.         EndIf
  180.  
  181.     ; Update workbench paths unless running Directory Opus 5.11 or 5.5 in WBR mode
  182.     Version >NIL: C:LoadWB 43
  183.     If WARN
  184.        C:LoadWB NEWPATH
  185.     Else
  186.         Version >NIL: C:LoadWB 60
  187.         If NOT WARN
  188.             C:LoadWB NEWPATH
  189.             EndIf
  190.         EndIf
  191.  
  192.     RequestChoice >NIL: "InitCD" "InitCD has set up some assigns and paths to run software from the CD.*NIf you wish to remove the CD from the drive, run InitCD again,*Notherwise the icon will stay on your Workbench." " OK "
  193.     EndIf
  194. ;;;
  195. SetEnv CDInit TRUE
  196.  
  197. LAB END
  198.  
  199. ;;; Remove commands made resident earlier
  200. Resident >NIL: RequestChoice REMOVE
  201. Resident >NIL: rx REMOVE
  202. Resident >NIL: Version REMOVE
  203. ;;;
  204.  
  205.